FSO 速查

作者:vkvi 來源:千一網絡(原創) 日期:2006-9-27

FSO - FileSystemObject 或 Scripting.FileSystemObject 的縮寫,為 IIS 內置組件,用于操作磁盤、文件夾或文本文件。FSO 的對象、方法和屬性非常的多,這里用示例的方式列出常用的,如果您要查看更詳盡的信息,請點擊這里下載 FileSystemObject 參考注意:《VBScript 語言參考》或《JScript 語言參考》中的:《FileSystemObject 用戶指南》和《Scripting 運行時庫參考》便是微軟給出的 FileSystemObject 完整參考。

FSO 不能操作二進制文件,要操作二進制文件,請使用:ADODB.Stream

創建文件
dim fso, f
set fso = server.CreateObject("Scripting.FileSystemObject")
set f = fso.CreateTextFile("C:\test.txt", true) '第二個參數表示目標文件存在時是否覆蓋
f.Write("寫入內容")
f.WriteLine("寫入內容并換行")
f.WriteBlankLines(3) '寫入三個空白行(相當于在文本編輯器中按三次回車)
f.Close()
set f = nothing
set fso = nothing

打開并讀文件
dim fso, f
set fso = server.CreateObject("Scripting.FileSystemObject")
set f = fso.OpenTextFile("C:\test.txt", 1, false) '第二個參數 1 表示只讀打開,第三個參數表示目標文件不存在時是否創建
f.Skip(3) '將當前位置向后移三個字符
f.SkipLine() '將當前位置移動到下一行的第一個字符,注意:無參數
response.Write f.Read(3) '從當前位置向后讀取三個字符,并將當前位置向后移三個字符
response.Write f.ReadLine() '從當前位置向后讀取直到遇到換行符(不讀取換行符),并將當前位置移動到下一行的第一個字符,注意:無參數
response.Write f.ReadAll() '從當前位置向后讀取,直到文件結束,并將當前位置移動到文件的最后
if f.atEndOfLine then
    response.Write("一行的結尾!")
end if
if f.atEndOfStream then
    response.Write("文件的結尾!")
end if
f.Close()
set f = nothing
set fso = nothing

打開并寫文件
dim fso, f
set fso = server.CreateObject("Scripting.FileSystemObject")
set f = fso.OpenTextFile("C:\test.txt", 2, false) '第二個參數 2 表示重寫,如果是 8 表示追加
f.Write("寫入內容")
f.WriteLine("寫入內容并換行")
f.WriteBlankLines(3) '寫入三個空白行(相當于在文本編輯器中按三次回車)
f.Close()
set f = nothing
set fso = nothing

判斷文件是否存在
dim fso
set fso = server.CreateObject("Scripting.FileSystemObject")
if fso.FileExists("C:\test.txt") then
    response.Write("目標文件存在")
else
    response.Write("目標文件不存在")
end if
set fso = nothing

移動文件
dim fso
set fso = server.CreateObject("Scripting.FileSystemObject")
call fso.MoveFile("C:\test.txt", "D:\test111.txt") '兩個參數的文件名部分可以不同
set fso = nothing

復制文件
dim fso
set fso = server.CreateObject("Scripting.FileSystemObject")
call fso.CopyFile("C:\test.txt", "D:\test111.txt") '兩個參數的文件名部分可以不同
set fso = nothing

刪除文件
dim fso
set fso = server.CreateObject("Scripting.FileSystemObject")
fso.DeleteFile("C:\test.txt")
set fso = nothing

創建文件夾
dim fso
set fso = server.CreateObject("Scripting.FileSystemObject")
fso.CreateFolder("C:\test") '目標文件夾的父文件夾必須存在
set fso = nothing

判斷文件夾是否存在
dim fso
set fso = server.CreateObject("Scripting.FileSystemObject")
if fso.FolderExists("C:\Windows") then
    response.Write("目標文件夾存在")
else
    response.Write("目標文件夾不存在")
end if
set fso = nothing

刪除文件夾
dim fso
set fso = server.CreateObject("Scripting.FileSystemObject")
fso.DeleteFolder("C:\test") '文件夾不必為空
set fso = nothing

你前面那位網友看了:官方證實 Firefox 4 默認搜索仍是 Google

▲▲▲嘿,歡迎轉載傳播本站原創文章,盡量保留來源噢。▲▲▲

文章評論
標題:必填
內容:
本站永遠終止與捏造“罪名”不支付廣告費的某度聯盟合作。
vkvi
vkvi

作者簡介: vkvi,致力于 .NET Web 開發、移動開發的技術推廣,在 .NET、SQL Server、Windows Server 等方面有深入研究和豐富經驗,10 年間共計撰寫文章 4000 余篇。 主持金融、國土、農業、電商等多個行業項目執行, 推行“技術提升生產力、人心決定成功率”的管理理論。 聯系他

最新22选5开奖公告